December 26, 2010 at 17:06

Big emails in Gmail

    As you know, Gmail does not allow sorting emails, in particular by size.
    There is a service that marks large letters with a label - www.findbigmail.com , but not everyone wants to give their password to anyone who is not clear.

    I wrote a script (on the groove) that creates the label “Big Mail” and marks it with all letters larger than 4MB. In the script, you need to replace the user name and password in Gmail, as well as, if you want, the size of the "large" emails.

    For the script to work in the classpath, there must be jars from here .

    Message iteration is slow (1-2 per second), so I set the number of the message being viewed to be printed so that you know that the script is not stuck.
    It takes a little time to collect all messages even with my quantity (approx. 20,000). But when accessing the message attributes (getSize ()) Message will go to the server.
    You can set this to Pre Fetch , then the total time may decrease, but the time for receiving a list of messages (i.e. you will wait without knowing whether he is alive at all) will increase (and seriously)

    Another interesting point: copyMessages () when applied to Gmail doesn’t copies or transfers, but simply adds a label.

    I mark messages one at a time, so that it doesn’t turn out that the script crashes (for example, because the network crashed) and did nothing.

    In general, there is much to improve - interactively ask for a username and password, do not mark those that are already marked, etc. Who needs it - will finish :)

    Remember to do IMAP - enable in the Gmail settings.



    // Mark large email messages in Gmail by "Bim Mail" label.
    // (c) Pavel :)
    // This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY

    import java.security.NoSuchProviderException
    import javax.mail.*

    final int BIG_MAIL_SIZE = 2 ** 22 //4Mb
    final String username = "xxx"
    final String password = "xxx"

    Properties props = System.getProperties()
    props.setProperty("mail.store.protocol", "imaps")
    props.setProperty("mail.imap.socketFactory.class", "javax.net.ssl.SSLSocketFactory")
    props.setProperty("mail.imap.socketFactory.fallback", "false")


    Folder all, big
    Store store

    try {
      Session session = Session.getDefaultInstance(props, null)
      store = session.getStore("imaps")
      final String mailaddress = "$username@gmail.com"



      store.connect("imap.gmail.com", mailaddress, password)
      def folderName = "[Gmail]/All Mail"
      all = store.getFolder(folderName)
      all.open(Folder.READ_WRITE);

      println("Creating BigMail ...")
      big = store.getFolder("BigMail")
      if (big.create(Folder.HOLDS_MESSAGES))
        println "Ok."
      else
        println "Failure. Already exists?"

      big.open(Folder.READ_WRITE);

      println "Downloading from folder $folderName ...."
      List messages = all.getMessages()
      println "Got ${messages.size()} messages"


      int count = 0
      messages.each {
        int size = it.getSize();

        if (size > BIG_MAIL_SIZE) {
          println "$count: Big mail: ${it.getSubject()} (${it.getSize()})"
          all.copyMessages([it].toArray(new Message[1]), big)

        }
        else {
          println count
        }
        count++

      }


    } catch (NoSuchProviderException e) {
      e.printStackTrace();
      System.exit(1);
    } catch (MessagingException e) {
      e.printStackTrace();
      System.exit(2);
    }
    finally {
      // Close connection
      all.close(false)
      big.close(false)
      store.close()
    }

    Java2html




    Tags:

    Also popular now: